addpkg: 1.0.0-1

PKGBUILD

@@ -0,0 +1,39 @@
+# Maintainer: Orhun Parmaksız <orhun@archlinux.org>
+
+pkgname=arti
+pkgver=1.0.0
+pkgrel=1
+pkgdesc="An implementation of Tor in Rust"
+arch=('x86_64')
+url="https://gitlab.torproject.org/tpo/core/arti"
+license=('MIT' 'Apache')
+depends=('sqlite' 'openssl' 'xz')
+makedepends=('cargo')
+source=("$pkgname-$pkgver.tar.gz::$url/-/archive/$pkgname-v$pkgver/$pkgname-$pkgname-v$pkgver.tar.gz")
+sha256sums=('4aa5f2f8ce98b913a843542f26895b2f4819829fa3dec9082fa1e8da5e274267')
+options=('!lto')
+
+prepare() {
+  mv "$pkgname-$pkgname-v$pkgver" "$pkgname-$pkgver"
+  cd "$pkgname-$pkgver"
+  cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
+}
+
+build() {
+  cd "$pkgname-$pkgver"
+  cargo build --release --frozen
+}
+
+check() {
+  cd "$pkgname-$pkgver"
+  cargo test --frozen
+}
+
+package() {
+  cd "$pkgname-$pkgver"
+  install -Dm 755 "target/release/$pkgname" -t "$pkgdir/usr/bin"
+  install -Dm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname"
+  install -Dm 644 LICENSE-MIT -t "$pkgdir/usr/share/licenses/$pkgname"
+}
+
+# vim:set ts=2 sw=2 et: