58 lines
1.5 KiB
Bash
58 lines
1.5 KiB
Bash
# Maintainer: Orhun Parmaksız <orhun@archlinux.org>
|
||
# Maintainer: kpcyrd <kpcyrd[at]archlinux[dot]org>
|
||
|
||
pkgname=arti
|
||
pkgver=1.2.7
|
||
pkgrel=1
|
||
pkgdesc="An implementation of Tor in Rust"
|
||
arch=('x86_64')
|
||
url="https://gitlab.torproject.org/tpo/core/arti"
|
||
license=('MIT' 'Apache-2.0')
|
||
depends=(
|
||
'gcc-libs'
|
||
'glibc'
|
||
'liblzma.so'
|
||
'libsqlite3.so'
|
||
'libssl.so'
|
||
)
|
||
makedepends=('cargo')
|
||
backup=('etc/arti.d/arti.toml')
|
||
options=('!lto')
|
||
source=("$pkgname-$pkgver.tar.gz::$url/-/archive/$pkgname-v$pkgver/$pkgname-$pkgname-v$pkgver.tar.gz")
|
||
sha256sums=('b40c71f682a2abe58728ee1d11735f450645a6d0778d7b076f5eae13973e7f2b')
|
||
b2sums=('32a9818e13607ed81d0132935617e6b29d6b44ff34e07e37e31f56e41b7b116ad933947dee70407f059f7debe0b8ebf4b353c8f28acb30be8077816304f54e93')
|
||
|
||
prepare() {
|
||
mv "$pkgname-$pkgname-v$pkgver" "$pkgname-$pkgver"
|
||
cd "$pkgname-$pkgver"
|
||
cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
|
||
}
|
||
|
||
build() {
|
||
cd "$pkgname-$pkgver"
|
||
cargo build --release --frozen --features full
|
||
}
|
||
|
||
check() {
|
||
cd "$pkgname-$pkgver"
|
||
cargo test --frozen
|
||
"target/release/$pkgname" --help
|
||
}
|
||
|
||
package() {
|
||
cd "$pkgname-$pkgver"
|
||
install -Dm 755 "target/release/$pkgname" -t "$pkgdir/usr/bin"
|
||
|
||
# config
|
||
install -Dm 640 crates/arti/src/arti-example-config.toml "$pkgdir/etc/arti.d/arti.toml"
|
||
|
||
# docs
|
||
install -Dm 644 -t "$pkgdir/usr/share/doc/$pkgname" \
|
||
README.md \
|
||
crates/arti/src/arti-example-config.toml
|
||
|
||
install -Dm 644 LICENSE-MIT -t "$pkgdir/usr/share/licenses/$pkgname"
|
||
}
|
||
|
||
# vim:set ts=2 sw=2 et:
|