58 lines
1.5 KiB
Bash
58 lines
1.5 KiB
Bash
# Maintainer: Orhun Parmaksız <orhun@archlinux.org>
|
||
# Maintainer: kpcyrd <kpcyrd[at]archlinux[dot]org>
|
||
|
||
pkgname=arti
|
||
pkgver=1.2.1
|
||
pkgrel=1
|
||
pkgdesc="An implementation of Tor in Rust"
|
||
arch=('x86_64')
|
||
url="https://gitlab.torproject.org/tpo/core/arti"
|
||
license=('MIT' 'Apache-2.0')
|
||
depends=(
|
||
'gcc-libs'
|
||
'glibc'
|
||
'liblzma.so'
|
||
'libsqlite3.so'
|
||
'libssl.so'
|
||
)
|
||
makedepends=('cargo')
|
||
backup=('etc/arti.d/arti.toml')
|
||
options=('!lto')
|
||
source=("$pkgname-$pkgver.tar.gz::$url/-/archive/$pkgname-v$pkgver/$pkgname-$pkgname-v$pkgver.tar.gz")
|
||
sha256sums=('d8008ee1b261a64b3f5d043f4073e2a26763b3669016e89549b990604e46ef70')
|
||
b2sums=('9749f1a6e0beb3512911c5406668ed3e975da7666f2ab91f31c73b3ace1c6eca1a56d000912dbc53bb93e05362f963be778af086ae0a6fa2aaf66fb33a296c31')
|
||
|
||
prepare() {
|
||
mv "$pkgname-$pkgname-v$pkgver" "$pkgname-$pkgver"
|
||
cd "$pkgname-$pkgver"
|
||
cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
|
||
}
|
||
|
||
build() {
|
||
cd "$pkgname-$pkgver"
|
||
cargo build --release --frozen --features full
|
||
}
|
||
|
||
check() {
|
||
cd "$pkgname-$pkgver"
|
||
cargo test --frozen
|
||
"target/release/$pkgname" --help
|
||
}
|
||
|
||
package() {
|
||
cd "$pkgname-$pkgver"
|
||
install -Dm 755 "target/release/$pkgname" -t "$pkgdir/usr/bin"
|
||
|
||
# config
|
||
install -Dm 640 crates/arti/src/arti-example-config.toml "$pkgdir/etc/arti.d/arti.toml"
|
||
|
||
# docs
|
||
install -Dm 644 -t "$pkgdir/usr/share/doc/$pkgname" \
|
||
README.md \
|
||
crates/arti/src/arti-example-config.toml
|
||
|
||
install -Dm 644 LICENSE-MIT -t "$pkgdir/usr/share/licenses/$pkgname"
|
||
}
|
||
|
||
# vim:set ts=2 sw=2 et:
|