commit 0f69d7d20ce9e1e444c74db1c1b13ae5c27b5fca
Author: Balakrishnan Balasubramanian <git.user@balki.me>
Date:   Wed Dec 31 11:01:58 2025 -0500

    initial commit

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 0000000..acd8afc
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,13 @@
+pkgbase = vimdecrypt-go-git
+	pkgdesc = Golang tool for decrypting VIM encrypted files
+	pkgver = r18.ccd1079
+	pkgrel = 1
+	url = https://github.com/doggeddog/vimdecrypt
+	arch = x86_64
+	license = MIT
+	makedepends = git
+	makedepends = go
+	source = git+https://github.com/doggeddog/vimdecrypt.git#branch=main
+	sha256sums = SKIP
+
+pkgname = vimdecrypt-go-git
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 0000000..8b96c7b
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,46 @@
+# Maintainer: Balakrishnan Balasubramanian <aur@balki.me>
+
+# Reference: https://wiki.archlinux.org/index.php?title=Go_package_guidelines#Sample_PKGBUILD
+
+_pkgname=vimdecrypt
+pkgname=vimdecrypt-go-git
+pkgrel=1
+pkgver=r18.ccd1079
+pkgdesc='Golang tool for decrypting VIM encrypted files'
+arch=('x86_64')
+url="https://github.com/doggeddog/vimdecrypt"
+license=('MIT')
+makedepends=('git' 'go')
+source=("git+$url.git#branch=main")
+sha256sums=('SKIP')
+
+prepare() {
+	cd "$_pkgname"
+	mkdir -p build/
+}
+
+pkgver() {
+	cd "$_pkgname"
+	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
+}
+
+build() {
+	cd "$_pkgname"
+	export CGO_CPPFLAGS="${CPPFLAGS}"
+	export CGO_CFLAGS="${CFLAGS}"
+	export CGO_CXXFLAGS="${CXXFLAGS}"
+	export CGO_LDFLAGS="${LDFLAGS}"
+	export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
+	go build -o build ./cmd/...
+}
+
+check() {
+	cd "$_pkgname"
+	go test ./...
+}
+
+package() {
+	cd "$_pkgname"
+	install -Dm755 build/"$_pkgname" "$pkgdir/usr/bin/$_pkgname"
+	install -Dm644 README.md "$pkgdir"/usr/share/doc/vimdecrypt-go/README.md
+}